@echo off
rem #####################################################################################################################
rem # BerkeleyParserBatch	Version: 0.1a											#
rem # von Robert Lange														#
rem # Script zur Verarbeitung mehrerer Dateien mit dem BerkeleyParser.							#
rem #####################################################################################################################
cls
setlocal
color 37
title ****BerkeleyParserBatch****
echo Verarbeitung mehrerer Dateien mit dem BerkeleyParser. Ein installiertes JRE wird vorausgesetzt.
echo.
set output_path=results
set gr_file=tuebadz_topf_no_edge.gr


set Dir=%homedrive%%homepath%\Desktop

rem ins Programmverzeichnis wechseln
pushd %~dp0

:START

if "%~1"=="" (
	cls
	echo Bitte die entsprechende[n] Datei[en]
	echo per Drag'n'drop auf das Skript-Icon ziehen!
	echo.
	echo Hinweis: Dateinamen duerfen keine Klammern am Ende enthalten!!!
	echo. 
	goto EXIT
	)



:BP_START
echo.
echo Erzeuge Datei[en]...

set p=0
for %%i in (%*) do (
	echo ___________________________________________________________________________________________________
	echo Erzeuge Datei[en] in diesem Verzeichnis: "%%~di%%~pi%output_path%\"
	if not exist "%%~di%%~pi%output_path%\" md "%%~di%%~pi%output_path%"
	if not exist "%%~di%%~pi%output_path%\%%~ni%%~xi" set /a "p+=1"
	
	rem java -jar berkeleyParser.jar -gr tuebadz_topf_no_edge.gr -inputFile "%%~fi" > "%%~di%%~pi%output_path%\%%~ni%%~xi"
	java -jar berkeleyParser.jar -gr %gr_file% -inputFile "%%~fi" > "%%~di%%~pi%output_path%\%%~ni%%~xi"
	echo.
	)
goto END

:ERROR
echo.
echo.
pause > nul
exit /b 1


:END
echo.
echo Ende. Insgesamt wurde[n] %p% Datei[en] erstellt.
:EXIT
pause > nul
endlocal && exit